Socialmetrica/Socialmetrica.package/NitterUser.class/instance/collectRawTweetsForPages..st

accessing
collectRawTweetsForPages: anInteger

	| pagesDict response customQuery |
	pagesDict := self getPagesContentsUpto: anInteger.
	response := TweetsCollection new.
	customQuery := Dictionary new
		               at: 'parameters' put: pagesDict keys;
		               at: 'date' put: DateAndTime now;
		               yourself.
	response query: customQuery.
	pagesDict keysAndValuesDo: [ :key :rawTweets | | temp | 
		temp := (rawTweets xpath: '//div[@class="timeline-item "]') asOrderedCollection
			collect: [ :xmlElement | xmlElement postCopy ].
		 temp do: [ :tweet | | tempTweet |
		 	tempTweet := Tweet new fromNitterHtmlItem: tweet.
		 	tempTweet metadata 
		 		at: DateAndTime now asString put: key;
		 		yourself.
		 	response messages add: tempTweet.
		 ]
	].
	response messages doWithIndex: [ :tweet :i | 
		| current previous |
		current := response messages at: i.
		i < response messages size ifTrue: [ 
			previous := response messages at: i + 1.
			current timelines
				at: self userName put: previous id;
				yourself ]].
	^ response.