GrafoscopioUtils/repository/Grafoscopio-Utils/LeTextualSnippet.extension.st

Extension { #name : #LeTextualSnippet }

{ #category : #'*Grafoscopio-Utils-Core' }
LeTextualSnippet >> asMarkdeep [
	"Inspired by Alpine.js and Assembler CSS 'x-' properties, we are going to use
	'st-' properties as a way to extend divs metadata regarding its contents."
	| output |
	output := '' writeStream.
	output
		nextPutAll: '<div st-class="', self class asString, '"'; lf;
		nextPutAll: '  st-data="', (STON toString: self metadata), '">'; lf;
		nextPutAll: self markdeepCustomOpener;
		nextPutAll: self contentAsString; lf;
		nextPutAll: self markdeepCustomCloser;
		nextPutAll: '</div>'; lf; lf.
	^ output contents
]

{ #category : #'*Grafoscopio-Utils-Core' }
LeTextualSnippet >> childrenIds [
	^ self children collect: [ :each | each uidString ]
]

{ #category : #'*Grafoscopio-Utils-Core' }
LeTextualSnippet >> markdeepCustomCloser [
	^ ''
]

{ #category : #'*Grafoscopio-Utils-Core' }
LeTextualSnippet >> markdeepCustomOpener [
	^ ''
]

{ #category : #'*Grafoscopio-Utils-Core' }
LeTextualSnippet >> metadata [
	^ OrderedDictionary new
		at: 'id' put: self uidString;
		at: 'parent' put: self parent uidString;
		at: 'created' put: self createTime asString;
		at: 'edited' put: self latestEditTime asString;
		at: 'creator' put: self createEmail asString;
		at: 'editor' put: self editEmail asString;
		yourself.
]