Fossil/repository/Fossil/FossilRepo.class.st

"
I model a fossil repository. For details about fossil see:

http://fossil-scm.org/

The protocols are named following Smalltalk conventions, but
also after the Fossil JSON API documentation at [1]

[1] https://docs.google.com/document/d/1fXViveNhDbiXgCuE7QDXQOKeFzf2qNUkBEgiUvoqFN4/view
"
Class {
	#name : #FossilRepo,
	#superclass : #Object,
	#instVars : [
		'local',
		'remote'
	],
	#category : #Fossil
}

{ #category : #authentication }
FossilRepo >> authTokenFor: anUserName withPassword: passwordString [
	^ ((self loginAs: anUserName withPassword: passwordString) at: 'payload') at: 'authToken'
]

{ #category : #authentication }
FossilRepo >> capabilities [
	| payload name permissions |
	payload := self rawCapabilities at: 'payload'.
	name := payload at: 'name'.
	permissions := ((payload at: 'permissionFlags') select: [ :item | item value ]) keys.
	^ Dictionary new
		at: 'name' put: name;
		at: 'permissions' put: permissions;
		yourself.
]

{ #category : #querying }
FossilRepo >> checkinsFor: relativeFilePath [
	"I get all histotical checkins information for a full file name, wich includes relative path 
	in the repository (i.e: 'Doc/Es/Tutoriales/tutorial.ston' or 'index.html')"
	| payload |
	payload := (self jsonDataFor: relativeFilePath)  at: 'payload' ifAbsent: [ 
		 self inform: 
			'WARNING! Key not found, verify the file name you are looking in this repository'. 
		 ^ self ].
	^ payload at: 'checkins'
]

{ #category : #querying }
FossilRepo >> commitsByDate [
	"I present the sum of all commit organized by date."
	| result |
	result := Dictionary new.
	self timeline do: [ :commit | | key |
		key := (DateAndTime fromUnixTime:  (commit at: 'timestamp' )) asDate.
		result at: key
			ifPresent: [ result at: key put: (result at: key) + 1  ] 
			ifAbsent: [ result at: key put: 1 ] ].
	^ result
]

{ #category : #'data visualization' }
FossilRepo >> commitsCalendarFrom: startYear to: endYear colored: colorsPalette [
	"I"

	| b colors dictionary valuedColors |
	dictionary := self commitsByDate.
	colors :=  RTColorPalette sequential colors: 9 scheme: 'Blues'.
	valuedColors := self commitsByDate collect: [ :v | colors at: v // 2 + 1 ].
	b := RTCalendarBuilder new.
	b dateShape rectangle
		size: 15;
		color: Color white;
		borderColor: Color lightGray.
	b monthShape shape: (b monthShapePath: 15.0).
	b yearShape
		composite: [ :comp | 
			comp
				add:
					(RTLabel new
						text: [ :d | d year ];
						height: 20).
			comp add: (RTBox new color: Color transparent) ].
	b dates: ((Year year: startYear) to: (Year year: endYear)).
	b dateLayout gapSize: 0.
	b monthLayout month.
	b yearLayout horizontalLine.
	b dateShape
		if: [ :d | dictionary includesKey: d ]
		color: [ :d | valuedColors at: d ].
	b dateInteraction popup.
	b build.
	(b view elements select: [ :e | e model isKindOf: Month ]) pushFront.
	^ b view
]

{ #category : #wiki }
FossilRepo >> createPage: pageName [
	^ NeoJSONReader fromString: (self jsonWikiDataFor: 'create/', pageName) 
]

{ #category : #wiki }
FossilRepo >> fetchPage: pageName [
	^ NeoJSONReader fromString: (self jsonWikiDataFor: 'get/', pageName) 
]

{ #category : #utility }
FossilRepo >> jsonDataFor: anUrlSegment [
	
	^ NeoJSONReader fromString: (self jsonStringFor: anUrlSegment)
]

{ #category : #querying }
FossilRepo >> jsonStringFor: aFileName [
	| baseUrl queryForJSONData |
	baseUrl := self remote.
	baseUrl addPathSegments: #('json' 'finfo').
	queryForJSONData := baseUrl queryAt: 'name' put: aFileName.
	^ (ZnEasy get: queryForJSONData) contents.
]

{ #category : #wiki }
FossilRepo >> jsonWikiDataFor: anUrlSegment [
	^ ZnClient new
		get: (self wikiRoot addPathSegment: anUrlSegment);
		contents.
]

{ #category : #querying }
FossilRepo >> lastHashNumberFor: aFileName [
	"I'm useful to see if local versions of files are updated to the last versions of the
	online repository"
	^ (self checkinsFor: aFileName) first at: 'uuid'
]

{ #category : #accessing }
FossilRepo >> local [
	^ local
]

{ #category : #accessing }
FossilRepo >> local: aLocalFilePath [
	local := aLocalFilePath
]

{ #category : #authentication }
FossilRepo >> loginAs: anUserName withPassword: password [
	| jsonData |
	jsonData := ZnClient new
		url: (self loginUrlWithName: anUserName andPassword: password);
		get;
		contents.
	^ NeoJSONReader fromString: jsonData
]

{ #category : #authentication }
FossilRepo >> loginUrlWithName: aUser andPassword: passwd [
	^ self jsonRoot 
		addPathSegment: 'login';
		queryAt: 'name' put: aUser;
		queryAt: 'password' put: passwd.
]

{ #category : #wiki }
FossilRepo >> pageList [
	^ NeoJSONReader fromString: (self jsonWikiDataFor: 'list')  
]

{ #category : #authentication }
FossilRepo >> rawCapabilities [
	^ NeoJSONReader fromString: (self jsonDataFor: 'cap')
]

{ #category : #accessing }
FossilRepo >> remote [
	^ remote
]

{ #category : #accessing }
FossilRepo >> remote: anUrlString [
	remote := anUrlString asUrl 
]

{ #category : #accessing }
FossilRepo >> timeline [
	"I return all information of all commits in a repository timeline."
	| baseUrl queryForJSONData |
	baseUrl := self remote addPathSegments: #('json' 'timeline' 'checkin').
	queryForJSONData := baseUrl queryAt: 'limit' put: 0.
	^ ((NeoJSONReader fromString: (queryForJSONData asUrl retrieveContents)) 
			at: 'payload') at: 'timeline'
]

{ #category : #authentication }
FossilRepo >> whoAmI [
	^ NeoJSONReader fromString: (self jsonDataFor: 'whoami')
]

{ #category : #wiki }
FossilRepo >> wikiRoot [
	^ self jsonRoot addPathSegment: 'wiki' 
]

{ #category : #wiki }
FossilRepo >> wikiTimeline [
	^ NeoJSONReader fromString: (self jsonWikiDataFor: 'timeline')  
]